Toujours répondre en "HTML" ?

[Original]

Bonjour à tous.

J'aimerai savoir si il est possible de forcer la réponse à n'importe quel e-mail au format HTML (même si l'email auquel nous répondons est au format brut/rich) ?

C'est surtout par curiosité

Merci d'avance !

[Pyrithe]

Je viens d'avoir @Patricia, notre experte ès Outlook, hors forum.

Elle m'explique qu'il n'y a pas d'automatisme possible. On choisi dans l'envoi du message, dans options, si on désire du texte brut, de l'HTML ou du texte enrichi (vérifié chez moi sur un 2007).

Merci à elle!!

[Mikael]

J'avais déjà cherché, sans avoir trouvé, comme l'a expliqué Pyrithe, il faut le faire manuellement pour les réponses.

Sinon c'est faisable via un addon comme celui ci, mais c'est payant (30$) http://www.outlook-apps.com/product/bells-whistles-for-outlook/

[Original]

Salut,

Merci pour vos réponses.

Ce sont exactement les mêmes choses que j'ai trouvé pendant mes recherches ^^

Du coup ça confirme bien que c'est impossible; je voulais voir si les Techs avaient mieux, mais sur le coup, raté

Merci encore!

[MathTek]

J'ai une solution, j'ai testé sous Outlook 2013, ça fonctionne. C'est une macro qui gère ça.

1. Ouvrir Outlook
2. Alt+F11 pour ouvrir le panneau VBA
3. Développer dans le panneau de gauche jusque voir ThisOutlookSession
4. Double cliquez dessus pour ouvrir a droite une session de code
5. Collez le code ci-dessous

Option Explicit 
 
Private WithEvents oExpl As Explorer 
Private WithEvents oItem As MailItem 
 
Private bDiscardEvents As Boolean
Private olFormat As OlBodyFormat 
 
 
Private Sub Application_Startup() 
     
   Set oExpl = Application.ActiveExplorer 
     
   bDiscardEvents = False
     <strong>
   'olFormat = olFormatPlain        '(*1) - reply using plain text  
   olFormat = olFormatHTML        '(*2) - reply using HTML </strong>
     
End Sub
 
Private Sub oExpl_SelectionChange() 
 
   On Error Resume Next
   Set oItem = oExpl.Selection.Item(1) 
     
End Sub
 
Private Sub oItem_Reply(ByVal Response As Object, Cancel As Boolean) 
 
   If bDiscardEvents Or oItem.BodyFormat = olFormat Then
       Exit Sub
   End If
     
   Cancel = True
 
   bDiscardEvents = True
     
   Dim oResponse As MailItem 
   Set oResponse = oItem.Reply 
   oResponse.BodyFormat = olFormat 
   oResponse.Display 
     
   bDiscardEvents = False
     
End Sub
 
Private Sub oItem_ReplyAll(ByVal Response As Object, Cancel As Boolean) 
 
   If bDiscardEvents Or oItem.BodyFormat = olFormat Then
       Exit Sub
   End If
 
   Cancel = True
   
   bDiscardEvents = True
     
   Dim oResponse As MailItem 
   Set oResponse = oItem.ReplyAll 
   oResponse.BodyFormat = olFormat 
   oResponse.Display 
     
   bDiscardEvents = False
     
End Sub
 
Private Sub oItem_Forward(ByVal Forward As Object, Cancel As Boolean) 
     
   If bDiscardEvents Or oItem.BodyFormat = olFormat Then
       Exit Sub
   End If
     
   Cancel = True
 
   bDiscardEvents = True
     
   Dim oResponse As MailItem 
   Set oResponse = oItem.Forward 
   oResponse.BodyFormat = olFormat 
   oResponse.Display 
     
   bDiscardEvents = False
     
End Sub

 

Attention tout de même à la sécurité de l’exécution des macro !

La partie en gras dans le code permet de changer si c'est tout le temps en HTML ou en RTF/plain text il suffit de commenter ou décommenter les lignes. Le code est pour du HTML only

 

Modifié 28 octobre 2015 par MathTek

[Original]

J'avais trouvé aussi cette macro, mais on voulait pas aller aussi loin ^^

Merci quand même MathTek